批處理新手入門導讀[視頻教程]批處理基礎視頻教程[視頻教程]VBS基礎視頻教程
[批處理文件精品]批處理版照片整理器[批處理文件精品]純批處理備份&還原驅動在線第三方下載
返回列表 發帖

[原創] [系列教程]批處理for語句從入門到精通[20101225更新]


____________________________版主提醒____________________________

  為了避免影響技術討論、提高看帖的舒適性,請大家不要在此帖下跟
無實質內容的口水帖,特別是純頂、純支持、純感謝、路過之類的帖子,
管理人員將不定期清理此類回帖,請大家多參與討論少灌水,與人方便,
終將給自己帶來方便,謝謝合作。
________________________________________________________________

  批處理是一門簡單的腳本語言,雖然不能獨當一面,但是,若作為工作中的輔助工具,絕對會讓大家有隨用隨寫、稱心如意的暢快感。

  和其他語言相比,批處理語言有其先天性的優勢:

  1、系統自帶,無需另行安裝;
  2、命令少,語句簡潔,上手非常快;
  3、編寫出來的腳本小巧玲瓏,隨寫隨用;

  但是,因為它以命令行方式工作,操作多有不便,在圖形界面大行其道的windows世界里,多多少少會讓大眾望而卻步;就算是對命令行有好感的新手,面對微軟有如天書的幫助文件,很多人也會敗下陣來,因此,論壇里很多會員也發出了編寫系統的批處理教程的呼聲。

  編寫系統的批處理新手教程,一直是論壇管理層討論的熱點問題,但是,各位管理人員大多都有工作在身,而系統的教程涉及的面是如此之廣,面對如此浩大的工程,僅憑一兩個人的力量,是難以做好的,因此,本人退而求其次,此次發布的教程,以專題的形式編寫,日后人手漸多之后,再考慮組織人力編寫全面的教程。

  之所以選擇最難的for,一是覺得for最為強大,是大多數人最希望掌握的;二是若寫其他命令教程,如果沒有for的基礎,展開來講解會無從下手;三是for也是批處理中最復雜最難掌握的語句,把它攻克了,批處理的學習將會一片坦途。

  這次的for語句系列教程,打算按照for語句的5種句式逐一展開,在講解 for /f 的時候,會穿插講解批處理中一個最為關鍵、也是新手最容易犯錯的概念:變量延遲,大綱如下:

一 前言
二 for語句的基本用法
三 for /f (含變量延遲)
四 for /r
五 for /d
六 for /l

  遵照 yibantiaokuan 的建議,在頂樓放出此教程的txt版本、word版本和pdf版本,以方便那些離線瀏覽的會員。

  由于本人水平有限,本教程尚存在不少錯誤,承蒙各位熱心會員的關注,一些已知的錯誤在(對“批處理for語句從入門到精通”的找茬行動:http://bbs.bathome.net/thread-14068-1-1.html)這個帖子中被指出,并在陸續更新之中,請各位務必注意指正帖中指出的錯誤之處,并歡迎各位在那個帖子中把本教程中的錯誤一一挑出,本人將抽空更新教程中有誤的地方。

下載地址:
http://pan.baidu.com/share/link?shareid=3613722265&uk=1124163200
19

評分人數

尺有所短寸有所長,學好批處理沒商量;
考慮問題復雜化,解決問題簡潔化。

心在天山,身老滄州。

一、前言

  在批處理中,for是最為強大的命令語句,它的出現,使得解析文本內容、遍歷文件路徑、數值遞增/遞減等操作成為可能;配合if、call、goto等流程控制語句,更是可以實現腳本復雜的自動化、智能化操作;合理使用for語句,還能使代碼大為簡化,免除各位編寫大量重復語句之苦。而能否熟練使用for語句,已經成為衡量一個人批處理水平高低最主要的標準。

  在這個系列教程中,我將通過實際應用中頻繁出現的例子,帶領大家步入for語句的神奇之門,一步步邁向for語句的魔幻殿堂,使得大家在實際的應用中,能獨立寫出簡潔高效的代碼,在批處理的世界里自由馳騁。

  注意:以下的講解,都是基于簡體中文版Windows XP Pro SP3的操作系統環境。
尺有所短寸有所長,學好批處理沒商量;
考慮問題復雜化,解決問題簡潔化。

心在天山,身老滄州。

TOP

二、for語句的基本用法[2008.11.9更新]

本帖最后由 Hello123World 于 2012-6-16 13:27 編輯

  正如色彩繽紛的七彩光芒是由紅綠藍三原色構成的一樣,最復雜的for語句,也有其基本形態,它的模樣是這樣的:
    (以下3條代碼修改由qzwqzw提供)  在cmd窗口中:
  1. FOR %variable IN (set) DO command [command-parameters]
復制代碼
  在批處理文件中:
  1. FOR %%variable IN (set) DO command [command-parameters],
復制代碼
  
    具體例子:
  1. For %i in (1 2 3) do @echo %i
復制代碼
之所以要區分cmd窗口和批處理文件兩種環境,是因為在這兩種環境下,命令語句表現出來的行為雖然基本一樣,但是在細節上還是稍有不同,最明顯的一個差異就是:在cmd窗口中,for之后的形式變量I必須使用單百分號引用,即%I;而在批處理文件中,引用形式變量I必須使用雙百分號,即%%I。為了方便起見,若不是特別強調,以下的講解都以批處理文件環境為例。

  我們先來看一下for語句的基本要素都有些什么:
  1、for、in和do是for語句的關鍵字,它們三個缺一不可;
  2、%%I是for語句中對形式變量的引用,就算它在do后的語句中沒有參與語句的執行,也是必須出現的;
  3、in之后,do之前的括號不能省略;
  4、command1表示字符串或變量,command2表示字符串、變量或命令語句;

  現在,你可能已經會寫一個簡單的for語句了,比如:
[code1]
  1. @echo off
  2. for %%I in (bbs.bathome.net) do echo %%I
  3. pause
復制代碼
  保存為批處理文件并執行,將會在彈出的批處理窗口中看到這樣的信息:
[result1]
bbs.bathome.net
請按任意鍵繼續...

  很快地,你會覺得這個for語句是如此的簡單,簡單到你絲毫感受不出它的強大:這個for語句,和我直接用echo語句沒什么兩樣啊!

  是的,演示代碼永遠都只是演示而已,就像大多數高級語言的教科書一樣,在引導新手學習的時候,基本上都是千篇一律地告訴大家如何編寫一個能顯示 hello world! 的窗口,從這些演示代碼中,你看不到它們具有多少實用性,你只是感到有點好奇:咦,居然彈出了一個窗口?片刻之后,你就會覺得索然無味。

  那好吧,為了讓大家對for更加感興趣,我們先來分析一下for語句的一些注意事項,之后,再讓大家看看更為強大的for語句實例。
  
  1、for語句的形式變量I,可以換成26個字母中的任意一個,這些字母會區分大小寫,也就是說,%%I和%%i會被認為不是同一個變量;形式變量I還可以換成其他的字符,但是,為了不與批處理中的%0~%9這10個形式變量發生沖突,請不要隨意把%%I替換為%%0 ~%%9中的任意一個;
  2、in和do之間的command1表示的字符串或變量可以是一個,也可以是多個,每一個字符串或變量,我們稱之為一個元素,每個元素之間,用空格鍵、跳格鍵、逗號、分號或等號分隔;
  3、for語句依次提取command1中的每一個元素,把它的值賦予形式變量I,帶到do后的command2中參與命令的執行;并且每次只提取一個元素,然后執行一次do后的命令語句,而無論這個元素是否被帶到command2中參與了command2的運行;當執行完一次do后的語句之后,再提取command1中的下一個元素,再執行一次command2,如此循環,直到command1中的所有元素都已經被提取完畢,該for語句才宣告執行結束;
  其中,第3點是最為關鍵的,它描述了for語句的執行過程,是for語句的精髓所在,大家一定要牢記這一條,才能深刻理解更為復雜的for流程。

  有了以上的基礎,我們再來看一個例子,這個例子修改了[code1]的部分內容,結果將大不一樣:
[code2]
  1. @echo off
  2. for %%I in (bbs,bathome,net) do echo %%I
  3. pause
復制代碼
  和[code1]的執行結果[result1]相比,[result2]發生了如下變化:

  1、顯示結果分成了3行(不算最后一行中文提示);
  2、每一行都從逗號處被切分;

  如果把 bbs.bathome.net 這個字符串中的點號換為空格、跳格或等號,執行結果將和example2的執行結果別無二致。

  現在,我們來分析一下[code2]代碼中for語句的執行過程:

  首先,for語句以逗號為分隔符,把 bbs,bathome.net 這個字符串切分成三個元素:bbs、bathome和cn,由此決定了do后的語句將會被執行3次;
  然后,第一次執行過程是這樣的:先把 bbs 這個字符串作為形式變量I的值,帶入do后的語句中加以執行,也就是執行 echo %%I 語句,此時的I值為bbs,因此,第一次執行的結果,將會在屏幕上顯示bbs這個字符串;第二次執行和第一次執行的過程是一樣的,只不過此時I的值已經被替換為command1中的第二個元素了,也就是 bathome 這個字符串;如此循環,當第三次echo執行完畢之后,整條for語句才算執行完畢,此時,將執行下一條語句,也就是pause命令。

  其實,這個例子只比上一個例子多了一點花樣,有趣了那么一點點:一條for語句的執行結果居然被分成了3行!

  為了讓大家見識一下for的真正威力,本人絞盡腦汁,翻帖無數,不得要領,萬般無奈之下,只好亮出了塵封在箱底多年的一段代碼:檢測當前硬盤都有哪些分區^_^
[code3]
  1. @echo off
  2. set str=c d e f g h i j k l m n o p q r s t u v w x y z
  3. echo 當前硬盤的分區有:
  4. for %%i in (%str%) do if exist %%i: echo %%i:
  5. pause
復制代碼
  這段代碼能檢測硬盤都有哪些分區,包括U盤和移動硬盤的分區,但是,當光驅中有盤的時候,也會被列出來,這是本代碼的一個缺憾,在以后的講解中,我將向大家講述如何消除這個瑕疵,敬請關注本系列的后續章節。

  高級應用:

  想知道當前目錄下都有哪些文件嗎?請用下面的代碼:
  1. @echo off
  2. for %%i in (*.*) do echo "%%i"
  3. pause
復制代碼
  想列出當前目錄下所有的文本文件嗎?請用下面的代碼:
  1. @echo off
  2. for %%i in (*.txt) do echo "%%i"
  3. pause
復制代碼
  想列出只用兩個字符作為文件名的文本文件嗎?(hello123world注:實際上這個代碼是輸出少于或等于兩個字符作為文件名的文本文件)請用下面的代碼:
  1. @echo off
  2. for %%i in (??.txt) do echo "%%i"
  3. pause
復制代碼
  題外話:

  1、列出當前目錄下各種文件的方法,最簡單的還是用dir命令,但是,從以上代碼中,各位可以加深對for語句執行流程的理解(用到了通配符*和?);
  2、注意:以上代碼不能列出含有隱藏或系統屬性的文件;(hello123world注:這里其實有一個很有趣的現象,windows中的系統文件一般具備兩種屬性——隱藏和系統;但是你如果測試的話就會發現,加上+s屬性,但是不加+h的文件是可以被簡單的for顯示出來的。
例如:
  1. @echo off
  2. attrib +s 1.txt
  3. For  %%i in (*.txt) do Echo %%i
  4. pause
復制代碼
這里的1.txt在結果中顯示出來了。所以“以上代碼不能列出含有隱藏或系統屬性的文件”是不準確的,而因該說成“以上代碼不能列出含有隱藏屬性的文件”)

  練習:用for語句建立test1.txt、test2.txt和test3.txt三個文本文件。

  更全面的練習請看這個帖子:for語句從入門到精通配套練習題
10

評分人數

尺有所短寸有所長,學好批處理沒商量;
考慮問題復雜化,解決問題簡潔化。

心在天山,身老滄州。

TOP

三、文本解析顯神威:for /f 用法詳解[2009.2.10更新]

本帖最后由 Hello123World 于 2012-6-16 13:40 編輯

    前言

  for /f 是個十分強大的家伙。

  如果說,for語句是批處理中最強大的語句的話,那么,for /f 就是精華中的精華。

  for /f 的強大,和它擁有眾多的開關密切相關。因為開關眾多,所以用法復雜,本章將分成若干小節,為大家逐一介紹強大的 for /f 語句。

    (一) 為解析文本而生:for /f 的基本用法

  所有的對象,無論是文件、窗體、還是控件,在所有的非機器語言看來,無外乎都是形如"c:\test.txt"、"CWnd"之類的文本信息;而所有的對象,具體的如ini文件中的某條配置信息、注冊表中的某個鍵值、數據庫中的某條記錄……都只有轉化為具有一定格式的文本信息,方可被代碼識別、操控。可以說,編程的很大一部分工作,都是在想方設法絞盡腦汁如何提取這些文本信息。

  而提取文本信息,則是for /f的拿手好戲:讀取文件內容;提取某幾行字符;截取某個字符片段;對提取到的內容再切分、打亂、雜糅……只要你所能想到的花樣,for /f 都會想方設法幫你辦到,因為,for /f 就是被設計成專門用于解析文本的。

  先來看個例子。

  假如有個文本文件test.txt,內容如下:
[txt1]
論壇的目標是:不求最大,但求最好,做最實用的批處理論壇。
論壇地址:bbs.bathome.net。
這里是:新手晉級的福地,高手論劍的天堂。
  那么,將如下代碼保存為test.cmd,并放在test.txt同一目錄下運行,將會在屏幕上原樣顯示test.txt的內容:
[code4]
  1. @echo off
  2. for /f %%i in (test.txt) do echo %%i
  3. pause
復制代碼
  這段代碼,主要是讓你樹立這樣一種觀念:讀取文本文件的內容(qzwqzw注:改為“逐行分析文本文件的內容”,因為讀取文本文件內容的方法命令有很多,比如重定向輸入,又比如type/more/find/sort等命令),請使用 for /f 語句!

  進階話題:for /f 語句是把整個test.txt一次性顯示出來的?

  在這段代碼中,雖然執行結果是把test.txt中的所有內容都顯示出來了,貌似 for /f 語句是把整個test.txt一次性顯示到屏幕上,實際上并非如此。

  無論for語句做何種變化,它的執行過程仍然遵循基本的for流程:依次處理每個元素,直到所有的元素都被處理為止。只不過在for /f語句中,這里的元素是指文件中的每一行,也就是說,for /f 語句是以行為單位處理文本文件的。這是一條極為重要的規則,在上一章中也強調過它的重要性,希望在接下來的學習過程中,你能時刻牢記這一原則,那么,很多問題將會迎刃而解。以下是驗證這一說法的演示代碼(在[code4]的基礎上添加了&pause語句):
[code5]
  1. @echo off
  2. for /f %%i in (test.txt) do echo %%i&pause
  3. pause
復制代碼
    (二) 切分字符串的利器:delims=

  也許你對[code4]這段代碼不屑一顧:不就是把test.txt的內容顯示出來了么?好像用處不大啊。

  好吧,我們來玩個魔術。

  還是[txt1]這段文本,把[code4]改造一下:
[code6]
  1. @echo off
  2. for /f "delims=," %%i in (test.txt) do echo %%i
  3. pause
復制代碼
  再次運行test.cmd,看到什么變化了嗎?!
[result2]
  1. 論壇的目標是:不求最大
  2. 論壇地址:bbs.bathome.net。
  3. 這里是:新手晉級的福地
  4. 請按任意鍵繼續...
復制代碼
  結果,你驚奇地發現,每行第一個逗號之后的所有內容都不見了(如果有不存在逗號的行,則保留原樣),也就說,你成功地提取到了每行第一個逗號之前的所有內容!

  試想一下,這段代碼會有什么用呢?

  如果別人給了你一個軟件清單,每行都是"英文軟件名(逗號)中文軟件名"的格式,而你卻只想保留英文名的時候,這段代碼將是多么有用啊!再假設,有這么一個IP文件,第一列是數字格式的IP地址,第二列是具體的空間地址,列與列之間用逗號分隔,而你想提取其中數字格式的IP,呵呵,我不說你也知道該怎么辦了吧?

  要是文本內容不是以逗號分隔,而是以其他符號分隔,那么,把"delims=,"的逗號換成相應的符號就可以了。

  在這里,我們引入了一個新的開關:"delims=,",它的含義是:以逗號作為被處理的字符串的分隔符號。

  在批處理中,指定分隔符號的方法是:添加一個形如 "delims=符號列表" 的開關,這樣,被處理的每行字符串都會被符號列表中羅列出來的符號切分開來。

  需要注意的是:如果沒有指定"delims=符號列表"這個開關,那么,for /f 語句默認以空格鍵或跳格鍵作為分隔符號。請把[txt1]中不同位置上的標點符號改為空格或跳格,再運行[code4]試試。

  進階話題:如果我要指定的符號不止一個,該怎么辦?

  在上面的講解中,我提到了指定分隔符號的方法:添加一個形如"delims=符號列表"的開關。不知道你注意到沒有,我的說法是"符號列表"而非"符號",這是大有講究的,因為,你可以一次性指定多個分隔符號!

  還是以[txt1]為例,把[code6]再改造一下:
[code7]
  1. @echo off
  2. for /f "delims=.," %%i in (test.txt) do echo %%i
  3. pause
復制代碼
  結果顯示:
[result3]
  1. 論壇的目標是:不求最大
  2. 論壇地址:bbs
  3. 這里是:新手晉級的福地
  4. 請按任意鍵繼續...
復制代碼
  這樣,第一個點號或第一個逗號之前的內容都被提取出來了。

  [code7]的執行過程是:逐行讀取test.txt中的內容,以點號和逗號切分每一行的內容(不存在點號和逗號的行,則不再切分,為了描述的方便,我們把被點號或逗號切分的一個一個的字符串片段,稱之為節),然后,for /f 會提取第一節的內容作為最終結果,顯示在屏幕上。需要注意的是,在這里,所有行的字符串被切分成了兩個以上的節,但是,[code7]的代碼只會提取第一節字符串的內容,因為 for /f 語句默認只提取第一節的符串。


    (三) 定點提取:tokens=

  上一節在講解 delims= 的時候,我一再強調 for /f 默認只能提取到第一節的內容,現在我們來思考一個問題:如果我要提取的內容不在第一節上,那怎么辦?

  這回,就該輪到 tokens= 出馬了。

  tokens= 后面一般跟的是數字,如 tokens=2,也可以跟多個,但是每個數字之間用逗號分隔,如 tokens=3,5,8,它們的含義分別是:提取第2節字符串、提取第3、第5和第8節字符串。注意,這里所說的“節”,是由 delims= 這一開關劃分的,它的內容并不是一成不變的。

  下面來看一個例子:
[txt2]
  1. 尺有所短,寸有所長,學好批處理沒商量,考慮問題復雜化,解決問題簡潔化。
復制代碼
  對[txt2]這段文本,假設它們保存在文件test.txt中,如果我想提取“學好批處理沒商量”這句話,該如何寫代碼呢?

  我們稍微觀察一下[txt2]就會發現,如果以逗號作為切分符號,就正好可以把“學好批處理沒商量”化為單獨的一“節”,結合上一節的講解,我們知道,"delims=," 這個開關是不可缺少的,而要提取的內容在以逗號切分的第3節上,那么,tokens= 后面的數字就應該是3了,最終的代碼如下:
[code8]
  1. @echo off
  2. for /f "delims=, tokens=3" %%i in (test.txt) do echo %%i
  3. pause
復制代碼
  如果我們現在要提取的不只一個“節”,而是多個,那又怎么辦呢?比如,要提取以逗號切分的第2節和第5節字符串,是寫成這樣嗎?
[code9]
  1. @echo off
  2. for /f "delims=, tokens=2,5" %%i in (test.txt) do echo %%i
  3. pause
復制代碼
  運行批處理后發現,執行結果只顯示了第2節的內容。

  原來,echo 后面的 %%i 只接收到了 tokens=2,5 中第一個數值2所代表的那個字符串,而第二個數值5所代表的字符串因為沒有變量來接收,所以就無法在執行結果中顯示出來了。

  那么,要如何接收 tokens= 后面多個數值所指代的內容呢?

  for /f 語句對這種情況做如下規定:

  如果 tokens= 后面指定了多個數字,如果形式變量為%%i,那么,第一個數字指代的內容用第一個形式變量%%i來接收,第二個數字指代的內容用第二個形式變量%%j來接收,第三個數字指代的內容用第三個形式變量%%k來接收……第N個數字指代的內容用第N個形式變量來接收,其中,形式變量遵循字母的排序,第N個形式變量具體是什么符號,由第一個形式變量來決定:如果第一個形式變量是%%i,那么,第二個形式變量就是%%j;如果第一個形式變量用的是%%x,那么,第二個形式變量就是%%y。

  現在回頭去看[code9],你應該知道如何修改才能滿足題目的要求了吧?修改結果如下:
[code10]
  1. @echo off
  2. for /f "delims=, tokens=2,5" %%i in (test.txt) do echo %%i %%j
  3. pause
復制代碼
  如果有這樣一個要求:顯示[txt2]中的內容,但是逗號要替換成空格,如何編寫代碼?

  結合上面所學的內容,稍加思索,你可能很快就得出了答案:
[code11]
  1. @echo off
  2. for /f "delims=, tokens=1,2,3,4,5" %%i in (test.txt) do echo %%i %%j %%k %%l %%m
  3. pause
復制代碼
  寫完之后,你可能意識到這樣一個問題:假如要提取的“節”數不是5,而是10,或者20,或者更多,難道我也得從1寫到10、20或者更多嗎?有沒有更簡潔的寫法呢?

  答案是有的,那就是:如果要提取的內容是連續的多“節”的話,那么,連續的數字可以只寫最小值和最大值,中間用短橫連接起來即可,比如 tokens=1,2,3,4,5 可以簡寫為 tokens=1-5 。

  還可以把這個表達式寫得更復雜一點:tokens=1,2-5,tokens=1-3,4,5,tokens=1-4,5……怎么方便就怎么寫吧。

  大家可能還看到一種比較怪異的寫法:
[code12]
  1. @echo off
  2. for /f "delims=, tokens=1,*" %%i in (test.txt) do echo %%i %%j
  3. pause
復制代碼
  結果,第一個逗號不見了,取代它的是一個空格符號,其余部分保持不變。

  其中奧妙就在這個星號上面。

  tokens=后面所接的星號具備這樣的功能:字符串從左往右被切分成緊跟在*之前的數值所表示的節數之后,字符串的其余部分保持不變,整體被*所表示的一個變量接收。

  理論講解是比較枯燥的,特別是為了嚴密起見,還使用了很多限定性的修飾詞,導致句子很長,增加了理解的難度,我們還是結合[code12]來講解一下吧。

  [txt2] 的內容被切分,切分符號為逗號,當切分完第一節之后,切分動作不再繼續下去,因為 tokens=1,* 中,星號前面緊跟的是數字1;第一節字符串被切分完之后,其余部分字符串不做任何切分,整體作為第二節字符串,這樣,[txt2]就被切分成了兩節,分別被變量%%i和變量%%j接收。

  以上幾種切分方式可以結合在一起使用。不知道下面這段代碼的含義你是否看得懂,如果看不懂的話,那就運行一下代碼,然后反復揣摩,你一定會更加深刻地理解本節所講解的內容的:
[code13]
  1. @echo off
  2. for /f "delims=, tokens=1,3-4,*" %%i in (test.txt) do echo %%i %%j %%k %%l
  3. pause
復制代碼
    (四) 跳過無關內容,直奔主題:skip=n

  很多時候,有用的信息并不是貫穿文本內容的始終,而是位于第N行之后的行內,為了提高文本處理的效率,或者不受多余信息的干擾,for /f 允許你跳過這些無用的行,直接從第N+1行開始處理,這個時候,就需要使用參數 skip=n,其中,n是一個正整數,表示要跳過的行數。例如:
[code14]
  1. @echo off
  2. for /f "skip=2" %%i in (test.txt) do echo %%i
  3. pause
復制代碼
  這段代碼將跳過頭兩行內容,從第3行起顯示test.txt中的信息。


    (五) 忽略以指定字符打頭的行:eol=

  在cmd窗口中敲入:for /?,相關的解釋為:
eol=c           - 指一個行注釋字符的結尾(就一個)
FOR /F "eol=; tokens=2,3* delims=, " %i in (myfile.txt) do @echo %i %j %k
    會分析 myfile.txt 中的每一行,忽略以分號打頭的那些行……

  第一條解釋狗屁不通,頗為費解:行注釋字符的結尾是什么意思?“(就一個)”怎么回事?結合第二條解釋,才知道eol有忽略指定行的功能。但是,這兩條解釋是互相矛盾的:到底是忽略以指定字符打頭的行,還是忽略以指定字符結尾的行?

  實踐是檢驗真理的唯一標準,還是用代碼來檢驗一下eol的作用吧:
[code15]
  1. @echo off
  2. for /f "eol=;" %%i in (test.txt) do echo %%i
  3. pause
復制代碼
  結果,那些以分號打頭的行沒有顯示出來。

  由此可見,第二條解釋是正確的,eol= 的準確含義是:忽略以指定字符打頭的行。而第一條的“結尾”純屬微軟在信口開河。

  那么,“(就一個)”又作何解釋呢?

  試試這個代碼:
[code16]
  1. @echo off
  2. for /f "eol=,;" %%i in (test.txt) do echo %%i
  3. pause
復制代碼
  此時,屏幕上出現 此時不應有 ;"。 的報錯信息。可見,在指定字符的時候,只能指定1個——在很多時候,我對這樣的設計頗有微詞而又無可奈何:為什么只能指定1個而不是多個?要忽略多個還得又是if又是findstr加管道來多次過濾,那效率實在太低下了——能用到的功能基本上都提供,但是卻又做不到更好,批處理,你的功能為什么那么弱?

  不知道大家注意到沒有,如果test.txt中有以分號打頭的行,那么,這些行在代碼[code14]的執行結果中將憑空消失。

  原來,for /f 語句是默認忽略以分號打頭的行內容的,正如它默認以空格鍵或跳格鍵作為字符串的切分字符一樣。(hello123world注:eol=;這種默認設置,在delims=;時變得無效。)

  很多時候,我們可以充分利用這個特點,比如,在設計即將用for讀取的配置文件的時候,可以在注釋文字的行首加上分號,例如在編寫病毒文件查殺代碼的時候,可以通過for語句來讀取病毒文件列表,那么,病毒文件列表.ini這個配置文件可以這樣寫:
;以下是常見的病毒文件,請見一個殺一個^_^
;copyleft:沒有
qq.exe
msn.exe
iexplore.exe


  如果要取消這個默認設置,可選擇的辦法是:

  1、為eol=指定另外一個字符;
  2、使用 for /f "eol=" 語句,也就是說,強制指定字符為空,就像對付delims=一樣。


    (六)如何決定該使用 for /f 的哪種句式?(兼談usebackq的使用)

  for /f %%i in (……) do (……) 語句有好幾種變形語句,不同之處在于第一個括號里的內容:有的是用單引號括起來,有的是用雙引號包住,有的不用任何符號包裹,具體格式為:

  1、for /f %%i in (文件名) do (……)
  2、for /f %%i in ('命令語句') do (……)
  3、for /f %%i in ("字符串") do (……)


  看到這里,我想很多人可能已經開始犯了迷糊了:如果要解決一個具體問題,面對這么多的選擇,如何決定該使用哪一條呢?

  實際上,當我在上面羅列這些語句的時候,已經有所提示了,不知道你是否注意到了。

  如果你一時無法參透其中奧妙,那也無妨,請聽我一一道來便是。

  1、當你希望讀取文本文件中的內容的話,第一個括號中不用任何符號包裹,應該使用的是第1條語句;例如:你想顯示test.txt中的內容,那么,就使用 for /f %%i in (test.txt) do echo %%i;
  2、當你讀取的是命令語句執行結果中的內容的話,第一個括號中的命令語句必須使用單引號包裹,應該使用的是第2條語句;例如:你想顯示當前目錄下文件名中含有test字符串的文本文件的時候,應該使用 for /f %%i in ('dir /a-d /b *test*.txt') do echo %%i 這樣的語句;
  3、當你要處理的是一個字符串的時候,第一個括號中的內容必須用雙引號括起來,應該是用的是第3條語句;例如:當你想把bbs.bathome.net這串字符中的點號換為短橫線并顯示出來的話,可以使用 for /f "delims=. tokens=1-3" %%i in ("bbs.bathome.net") do echo %%i-%%j-%%k 這樣的語句。

  很顯然,第一個括號里是否需要用符號包裹起來,以及使用什么樣的符號包裹,取決于要處理的對象屬于什么類型:如果是文件,則無需包裹;如果是命令語句,則用單引號包裹;如果是字符串,則使用雙引號括起來。

  當然,事情并不是絕對如此,如果細心的你想到了批處理中難纏的特殊字符,你肯定會頭大如斗。

  或許你頭腦中靈光一閃,已經想到了一個十分頭痛的問題:在第1條語句中,如果文件名中含有空格或&,該怎么辦?

  照舊嗎?

  拿個叫 test 1.txt 的文件來試試。

  你很快寫好了代碼,新建文件-->碼字-->保存為批處理,前后費時不到1分鐘:
[code17]
  1. @echo off
  2. for /f %%i in (test 1.txt) do echo %%i
  3. pause
復制代碼
  你興沖沖地雙擊批處理,運行后,屏幕上出現了可恥的報錯信息:系統找不到文件 test 。

  當你把 test 1.txt 換成 test&1.txt 后,更怪異的事情發生了:CMD窗口在你眼前一閃而過,然后,優雅地消失了。

  你可能覺得自己的代碼寫錯了某些符號,你再仔細的檢查了一次,確認沒有筆誤,然后,你再次雙擊批處理,結果問題照舊;你開始懷疑其他程序對它可能有影響,于是關掉其他窗口,再運行了一次,問題依舊;你不服氣地連續運行了好幾次,還是同樣的結果。

  怪哉!

  你一拍大腿,猛然想起了一件事:當路徑中含有特殊字符的時候,應該使用引號把路徑括起來。對,就是它了!

  但是,當你把代碼寫出來之后,你很快就焉了:for /f %%i in ("test 1.txt") do echo %%i,這不就是上面提到的第3條 for /f 命令的格式嗎?批處理會把 test 1.txt 這個文件名識別為字符串啊!

  你百無聊賴地在CMD窗口中輸入 for /? ,并重重地敲下了回車,漫無目的地在幫助信息中尋找,希望能找到點什么。

  結果還真讓你到了點什么。

  你看到了這樣的描述:
        usebackq        - 指定新語法已在下類情況中使用:
                          在作為命令執行一個后引號的字符串并且一個單
                          引號字符為文字字符串命令并允許在 filenameset
                          中使用雙引號擴起文件名稱。


  但是,通讀一遍之后,你卻如墜五里霧中,不知所云。

  還好,下面有個例子,并配有簡單的說明:

      FOR /F "usebackq delims==" %i IN (`set`) DO @echo %i
    會枚舉當前環境中的環境變量名稱。


  你仔細對比了for /f語句使用usebackq和不使用usebackq時在寫法上的差別,很快就找到了答案:當使用了usebackq之后,如果第一個括號中是一條命令語句,那么,就要把單引號'改成后引號`(鍵盤左上角esc鍵下面的那個按鍵,與~在同一鍵位上)。

  回過頭去再看那段關于usebackq的描述,字斟句酌,反復揣摩,終于被你破譯了天機:usebackq 是一個增強型參數,當使用了這個參數之后,原來的for語句中第一個括號內的寫法要做如下變動:如果第一個括號里的對象是一條命令語句的話,原來的單引號'要改為后引號`;如果第一個括號里的對象是字符串的話,原來的雙引號"要改為單引號';如果第一個括號里的對象是文件名的話,要用雙引號"括起來。

  驗證一下,把[code17]改寫成如下代碼:
[code18]
  1. @echo off
  2. for /f "usebackq" %%i in ("test 1.txt") do echo %%i
  3. pause
復制代碼
  測試通過!

  此時,你很可能會仰天長嘆:Shit,微軟這該死的機器翻譯!

  至于把[code17]代碼中的空格換成&后,CMD窗口會直接退出,那是因為&是復合語句的連接符,CMD在預處理的時候,會優先把&前后兩部分作為兩條語句來解析,而不是大家想象中的一條完整的for語句,從而產生了嚴重的語法錯誤。因為牽涉到預處理機制問題,不屬于本節要討論的內容,在此不做詳細講解。

  這個時候,我們會吃驚地發現,區區一條for語句,竟然有多達6種句型:

  1、for /f %%i in (文件名) do (……)
  2、for /f %%i in ('命令語句') do (……)
  3、for /f %%i in ("字符串") do (……)
  4、for /f "usebackq" %%i in ("文件名") do (……)
  5、for /f "usebackq" %%i in (`命令語句`) do (……)
  6、for /f "usebackq" %%i in ('字符串') do (……)

  其中,4、5、6由1、2、3發展而來,他們有這樣的對應關系:1-->4、2-->5、3-->6。

  好在后3種情形并不常用,所以,牢牢掌握好前三種句型的適用情形就可以了,否則,要在這么多句型中確定選擇哪一條語句來使用,還真有點讓人頭腦發懵。

  至于 for /f 為什么要增加usebacq參數,我只為第4條語句找到了合理的解釋:為了兼容文件名中所帶的空格或&。它在第5、6條語句中為什么還有存在的必要,我也不是很明白,這有待于各位去慢慢發現。(hello123world注:這種解釋雖然有點不靠譜,但也算一種解釋,大家將就看看吧。啟用usebackq選項的時候,“文件名”取代了“字符串”,那么“字符串”只好改變為“命令語句”,“命令語句”只好用后引號重新表示——簡而言之,是“文件名”符號改變引起的蝴蝶效應。言外之意:usebackq除了在處理帶空格的文件名時會用到外,根本就沒有其它的出場機會和存在價值。)

[ 本帖最后由 namejm 于 2010-12-25 03:22 編輯 ]
9

評分人數

    • jrx401: 感謝詳細的解釋。技術 + 1
    • chris0912: 感謝分享技術 + 1
    • L-殤: 已將QQ,MSN,IE刪除,現用GG與YY...技術 + 1
    • an410398183: 學習學習技術 + 1
    • wangx: 對我的幫助很大,謝謝分享技術 + 1
尺有所短寸有所長,學好批處理沒商量;
考慮問題復雜化,解決問題簡潔化。

心在天山,身老滄州。

TOP

(七)變量延遲詳解[2009.2.12更新]

  變量延遲在for語句中起著至關重要的作用,不只是在for語句中,在其他的復合語句中,它也在幕后默默地工作著,為了突出它的重要性,本節內容在單獨的樓層中發出來,希望引起大家的重視。

  對于批處理新手而言,“變量延遲”這個概念很可能聞所未聞,但是,它卻像一堵橫亙在你前進道路上的無形高墻,你感受不到它的存在,但當你試圖往前沖時,它會把你狠狠地彈回來,讓你無法逾越、無功而返;而一旦找到了越過它的方法,你就會發現,在for的世界里,前面已經是一片坦途,而你對批處理的理解,又上升到了一個新的境界。

  例如,你編寫了這樣一個代碼:
[code19]
  1. @echo off
  2. set num=0&&echo %num%
  3. pause
復制代碼
  你的本意是想對變量num賦值之后,再把這個值顯示出來,結果,顯示出來的并不是0,而是顯示:ECHO 處于關閉狀態。

  之所以會出錯,是因為“變量延遲”這個家伙在作怪。

  在講解變量延遲之前,我們需要了解一下批處理的執行過程,它將有助于我們深入理解變量延遲。

  批處理的執行過程是怎樣的呢?

  “自上而下,逐條執行”,我想,這個經典的說法大家都已經耳熟能詳了,沒事的時候倒著念,也還別有一番古韻呢^_^,但是,我想問大家的是,大家真的深刻地理解了這句話的含義了嗎?

  “自上而下”,這一條和我們本節的講解關系不大,暫時略過不說,后一條,“逐條執行”和變量延遲有著莫大的干系,它是我們本節要關注的重點。

  很多人往往認為一行代碼就是一條語句,從而把“逐條執行”與“逐行執行”等同起來,這就大錯特錯了。

  莫非“逐條執行”里暗藏著玄機?

  正是如此。

  “逐條”并不等同于“逐行”。這個“條”,是“一條完整的語句”的意思,并不是指“一行代碼”。在批處理中,是不是一條完整的語句,并不是以行來論的,而是要看它的作用范圍。

  什么樣的語句才算“一條完整的語句”呢?

  1、在復合語句中,整個復合語句是一條完整的語句,而無論這個復合語句占用了多少行的位置。常見的復合語句有:for語句、if……else語句、用連接符&、||和&&連接的語句,用管道符號|連接的語句,以及用括號括起來的、由多條語句組合而成的語句塊;
  2、在非復合語句中,如果該語句占據了一行的位置,則該行代碼為一條完整的語句。
  例如:
[code20]
  1. @echo off
  2. set num=0
  3. for /f %%i in ('dir /a-d /b *.exe') do (
  4.     set /a num+=1
  5.     echo num 當前的值是 %num%
  6. )
  7. echo 當前目錄下共有 %num% 個exe文件
  8. dir /a-d /b *.txt|findstr "test">nul&&(
  9.     echo 存在含有 test 字符串的文本本件
  10. )||echo 不存在含有 test 字符串的文本文件
  11. if exist test.ini (
  12.     echo 存在 test.ini 文件
  13. ) else echo 不存在 test.ini 文件
  14. pause
復制代碼
  上面的代碼共有14行,但是只有完整的語句只有7條,它們分別是:

  第1條:第1行的echo語句;
  第2條:第2行的set語句;
  第3條:第3、4、5、6行上的for復合語句;
  第4條:第7行的echo語句;
  第5條:第8、9、10行上用&&和||連接的復合語句;
  第6條:第11、12、13行上的if……else復合語句;
  第7條:第14行上的pause語句。

  在這里,我之所以要花這么長的篇幅來說明一行代碼并不見得就是一條語句,是因為批處理的執行特點是“逐條”執行而不是“逐行”執行,澄清了這個誤解,將會更加理解批處理的預處理機制。

  在代碼“逐條”執行的過程中,cmd.exe這個批處理解釋器會對每條語句做一些預處理工作,這就是批處理中大名鼎鼎的“預處理機制”。

  預處理的大致情形是這樣的:首先,把一條完整的語句讀入內存中(不管這條語句有多少行,它們都會被一起讀入),然后,識別出哪些部分是命令關鍵字,哪些是開關、哪些是參數,哪些是變量引用……如果代碼語法有誤,則給出錯誤提示或退出批處理環境;如果順利通過,接下來,就把該條語句中所有被引用的變量及變量兩邊的百分號對,用這條語句被讀入內存之就已經賦予該變量的具體值來替換……當所有的預處理工作完成之后,批處理才會執行每條完整語句內部每個命令的原有功能。也就是說,如果命令語句中含有變量引用(變量及緊鄰它左右的百分號對),并且某個變量的值在命令的執行過程中被改變了,即使該條語句內部的其他地方也用到了這個變量,也不會用最新的值去替換它們,因為某條語句在被預處理的時候,所有的變量引用都已經被替換成字符串常量了,變量值在復合語句內部被改變,不會影響到語句內部的其他任何地方。

  順便說一下,運行代碼[code20]之后,將在屏幕上顯示當前目錄下有多少個exe文件,是否存在含有 test 字符串的文本文件,以及是否存在 test.ini 這個文件等信息。讓很多人百思不得其解的是:如果當前目錄下存在exe文件,那么,有多少個exe文件,屏幕上就會提示多少次 "num 當前的值是 0" ,而不是顯示1到N(N是exe文件的個數)。

  結合上面兩個例子,我們再來分析一下,為什么這兩段代碼的執行結果和我們的期望有一些差距。

  在[code19]中,set num=0&&echo %num%是一條復合語句,它的含義是:把0賦予變量num,成功后,顯示變量num的值。

  雖然是在變量num被賦值成功后才顯示變量num的值,但是,因為這是一條復合語句,在預處理的時候,&&后的%num%只能被set語句之前的語句賦予變量num的具體值來替換,而不能被復合語句內部、&&之前的set語句對num所賦予的值來替換,可見,此num非彼num。可是,在這條復合語句之前,我們并沒有對變量num賦值,所以,&&之后的%num%是空值,相當于在&&之后只執行了 echo 這一命令,所以,會顯示 echo 命令的當前狀態,而不是顯示變量num的值(雖然該變量的值被set語句改變了)。

  在[code20]中,for語句的含義是:列舉當前目錄下的exe文件,每發現一個exe文件,變量num的值就累加1,并顯示變量num的值。

  看了對[code19]的分析之后,再來分析[code20]就不再那么困難了:第3、4、5行上的代碼共同構成了一條完整的for語句,而語句"echo num 當前的值是 %num%"與"set /a num+=1"同處復合語句for的內部,那么,第4行上set改變了num的值之后,并不能對第5行上的變量num有任何影響,因為在預處理階段,第5行上的變量引用%num%已經被在for之前就賦予變量num的具體值替換掉了,它被替換成了0(是被第2行上的set語句賦予的)。

  如果想讓代碼[code19]的執行結果中顯示&&之前賦予num的值,讓代碼[code20]在列舉exe文件的時候,從1到N地顯示exe文件的數量,那又該怎么辦呢?

  對代碼[code19],可以把用&&連接復合語句拆分為兩條單獨的語句,寫成:
  1. @echo off
  2. set num=0
  3. echo %num%
  4. pause
復制代碼
  但是,這不是我們這次想要的結果。

  對這兩段代碼都適用的辦法是:使用變量延遲擴展語句,讓變量的擴展行為延遲一下,從而獲取我們想要的值。

  在這里,我們先來充下電,看看“變量擴展”有是怎么一回事。

  用CN-DOS里批處理達人willsort的原話,那就是:“在許多可見的官方文檔中,均將使用一對百分號閉合環境變量以完成對其值的替換行為稱之為“擴展(expansion)”,這其實是一個第一方的概念,是從命令解釋器的角度進行稱謂的,而從我們使用者的角度來看,則可以將它看作是引用(Reference)、調用(Call)或者獲取(Get)。”(見:什么情況下該使用變量延遲?http://www.cn-dos.net/forum/viewthread.php?tid=20733)說得直白一點,所謂的“變量擴展”,實際上就是很簡單的這么一件事情:用具體的值去替換被引用的變量及緊貼在它左右的那對百分號。

  既然只要延遲變量的擴展行為,就可以獲得我們想要的結果,那么,具體的做法又是怎樣的呢?

  一般說來,延遲變量的擴展行為,可以有如下選擇:

  1、在適當位置使用 setlocal enabledelayedexpansion 語句;
  2、在適當的位置使用 call 語句。


  使用 setlocal enabledelayedexpansion 語句,那么,[code19]和[code20]可以分別修改為:
  1. @echo off
  2. setlocal enabledelayedexpansion
  3. set num=0&&echo !num!
  4. pause
復制代碼
  1. @echo off
  2. set num=0
  3. setlocal enabledelayedexpansion
  4. for /f %%i in ('dir /a-d /b *.exe') do (
  5.     set /a num+=1
  6.     echo num 當前的值是 !num!
  7. )
  8. echo 當前目錄下共有 %num% 個exe文件
  9. dir /a-d /b *.txt|findstr "test">nul&&(
  10.     echo 存在含有 test 字符串的文本本件
  11. )||echo 不存在含有 test 字符串的文本文件
  12. if exist test.ini (
  13.     echo 存在 test.ini 文件
  14. ) else echo 不存在 test.ini 文件
  15. pause
復制代碼
  使用第call語句,那么,[code19]和[code20]可以分別修改為:
  1. @echo off
  2. set num=0&&call echo %%num%%
  3. pause
復制代碼
  1. @echo off
  2. set num=0
  3. for /f %%i in ('dir /a-d /b *.exe') do (
  4.     set /a num+=1
  5.     call echo num 當前的值是 %%num%%
  6. )
  7. echo 當前目錄下共有 %num% 個exe文件
  8. dir /a-d /b *.txt|findstr "test">nul&&(
  9.     echo 存在含有 test 字符串的文本本件
  10. )||echo 不存在含有 test 字符串的文本文件
  11. if exist test.ini (
  12.     echo 存在 test.ini 文件
  13. ) else 不存在 test.ini 文件
  14. pause
復制代碼
  由此可見,如果使用 setlocal enabledelayedexpansion 語句來延遲變量,就要把原本使用百分號對閉合的變量引用改為使用感嘆號對來閉合;如果使用call語句,就要在原來命令的前部加上 call 命令,并把變量引用的單層百分號對改為雙層。 其中,因為call語句使用的是雙層百分號對,容易使人犯迷糊,所以用得較少,常用的是使用 setlocal enabledelayedexpansion 語句(set是設置的意思,local是本地的意思,enable是能夠的意思,delayed是延遲的意思,expansion是擴展的意思,合起來,就是:讓變量成為局部變量,并延遲它的擴展行為)。

  通過上面的分析,我們可以知道:

  1、為什么要使用變量延遲?因為要讓復合語句內部的變量實時感知到變量值的變化。
  2、在哪些場合需要使用變量延遲語句?在復合語句內部,如果某個變量的值發生了改變,并且改變后的值需要在復合語句內部的其他地方被用到,那么,就需要使用變量延遲語句。而復合語句有:for語句、if……else語句、用連接符&、||和&&連接的語句、用管道符號|連接的語句,以及用括號括起來的、由多條語句組合而成的語句塊。最常見的場合,則是for語句和if……else語句。
  3、怎樣使用變量延遲?

  方法有兩種:
  ① 使用 setlocal enabledelayedexpansion 語句:在獲取變化的變量值語句之前使用setlocal enabledelayedexpansion,并把原本使用百分號對閉合的變量引用改為使用感嘆號對來閉合;
  ② 使用 call 語句:在原來命令的前部加上 call 命令,并把變量引用的單層百分號對改為雙層。


  “變量延遲”是批處理中一個十分重要的機制,它因預處理機制而生,用于復合語句,特別是大量使用于強大的for語句中。只有熟練地使用這一機制,才能在for的世界中如魚得水,讓自己的批處理水平更上一層樓。很多時候,對for的處理機制,我們一直是霧里看花,即使偶有所得,也只是只可意會難以言傳。希望大家反復揣摩,多加練習,很多細節上的經驗,是只有通過大量的摸索才能得到的。Good Luck!

  本節內容在原理上參考了這篇文章:什么情況下該使用變量延遲?http://www.cn-dos.net/forum/viewthread.php?tid=20733,在本論壇中的地址是:http://bbs.bathome.net/viewthread.php?tid=2899

  特別鳴謝:willsort。
1

評分人數

尺有所短寸有所長,學好批處理沒商量;
考慮問題復雜化,解決問題簡潔化。

心在天山,身老滄州。

TOP

四、翻箱倒柜遍歷文件夾:for /r

  (一)for /r 的作用及用法

  按照幫助信息里文縐縐的說法,for /r 的作用是“遞歸”,我們換一個通俗一點的,叫“遍歷文件夾”。

  更詳細的解釋就是:在下面的語句中,如果“元素集合”中只是一個點號,那么,這條語句的作用就是:列舉“目錄”及其之下的所有子目錄,對這些文件夾都執行“命令語句集合”中的命令語句。其作用與嵌套進 for /f 復合語句的 "dir /ad /b /s 路徑" 功能類似。如果省略了“目錄”,將在當前目錄下執行前面描述的操作。
for /r 目錄 %%i in (元素集合) do 命令語句集合

  先來個代碼增強一下印象:
[code21]
  1. @echo off
  2. for /r d:\test %%i in (.) do echo %%i
  3. pause
復制代碼
  執行的結果如下所示:
d:\test\.
d:\test\1\.
d:\test\2\.
d:\test\3\.

  效果就是顯示 d:\test 目錄及其之下是所有子目錄的路徑,其效果與 dir /ad /b /s d:\test 類似。若要說到兩者的區別,可以歸納出3點:

  1、for /r 列舉出來的路徑最后都帶有斜杠和點號,而 dir 語句則沒有,會對獲取到的路徑進行進一步加工產生影響;
  2、for /r 不能列舉帶隱藏屬性的目錄,而 dir 語句則可以通過指定 /a 后面緊跟的參數來獲取帶指定屬性的目錄,更加靈活;
  3、若要對獲取到的路徑進行進一步處理,則需要把 dir 語句放入 for /f 語句中進行分析,寫成 for /f %%i in ('dir /ad /b /s') do …… 的形式;由于 for /r 語句是邊列舉路徑邊進行處理,所以,在處理大量路徑的時候,前期不會感到有停頓,而 for /f 語句則需要等到 dir /ad /b /s 語句把所有路徑都列舉完之后,再讀入內存進行處理,所以,在處理大量路徑的時候,前期會感到有明顯的停頓。

  第2點差別很容易被大家忽視,導致用 for /r 列舉路徑的時候會造成遺漏;而第3點則會讓大家有更直觀的感受,很容易感覺到兩者之間的差別。

  要是“元素集合”不是點號呢?那又如何?

  來看看這個代碼:
[code22]
  1. @echo off
  2. for /r d:\test %%i in (a b c) do echo %%i
  3. pause
復制代碼
  運行的結果是:
D:\test\1\a
D:\test\1\b
D:\test\1\c
D:\test\2\a
D:\test\2\b
D:\test\2\c
D:\test\3\a
D:\test\3\b
D:\test\3\c

  原來,它的含義是:列舉 d:\test 及其所有的子目錄,對所有的目錄路徑都分別添加a、b、c之后再顯示出來。

  再來看一個代碼:
[code23]
  1. @echo off
  2. for /r d:\test %%i in (*.txt) do echo %%i
  3. pause
復制代碼

  運行結果是:
D:\test\test.txt
D:\test\1\1.txt
D:\test\1\2.txt
D:\test\2\a.txt
D:\test\2\b.txt
D:\test\3\1.txt

  這段代碼的含義是:列舉 d:\test 及其所有子目錄下的txt文本文件(以.txt結尾的文件夾不會被列出來)。

  我們再回過頭來歸納一下這個語句的作用:
for /r 目錄 %%i in (元素集合) do 命令語句集合

  上面語句的作用是:

  1、列舉“目錄”及該目錄路徑下所有子目錄,并把列舉出來的目錄路徑和元素集合中的每一個元素拼接成形如“目錄路徑\元素”格式的新字符串,然后,對每一條這樣的新
字符串執行“命令語句集合”中的每一條命令;
  特別的是:當“元素集合”帶以點號分隔的通配符?或*的時候,把“元素集合”視為文件(不視為文件夾),整條語句的作用是匹配“目錄”所指文件夾及其所有子文件夾下
匹配的文件;若不以點號分隔,則把“元素集合”視為文件夾(不視為文件);
  2、當省略掉“目錄”時,則針對當前目錄;
  3、當元素集合中僅僅是一個點號的時候,將只列舉目錄路徑;

  (二)for /r 還是 dir /ad /b /s?列舉目錄時該如何選擇

  前面已經說過,當列舉目錄時,for /r 和 dir /ad /b /s 的效果是非常類似的,這就產生了一個問題:當我要獲取目錄路徑并進行進一步處理的時候,兩者之間,我該如何選擇?

  這個問題,前面其實已經有過一些討論,現在我們再來作詳細的分析。

  我們來看一下兩者各自的優缺點:

  1、for /r:

    1)優點:

    ① 只通過1條語句就可以同時實現獲取目錄路徑和處理目錄路徑的操作;
    ② 遍歷文件夾的時候,是邊列舉邊處理的,獲取到一條路徑就處理一條路徑,內存占用小,處理大量路徑的時候不會產生停頓感;

    2)缺點:

    ① 不能獲取到帶隱藏屬性的目錄,會產生遺漏;
    ② 不能獲取帶指定屬性的目錄

  2、dir /ad /s:

    1)優點:

    ① 能一次性獲取帶任意屬性的目錄,不會產生遺漏;
    ② 能通過指定不同的參數獲取帶任意屬性的目錄,更具靈活性。

    2)缺點:

    ① dir /ad /s 語句僅能獲取到目錄路徑,若要實現進一步的處理,還需要嵌入 for /f 語句中才能實現,寫法不夠簡潔;
    ② 嵌入 for /f 語句之后,需要寫成 for /f "delims=" %%i in ('dir /ad /b /s') do …… 的格式,受 for /f 語句運行機制的制約,需要先列舉完所有的路徑放入內存之后,才能對每一條路徑進行進一步的處理,處理大量路徑時,內存占用量偏大,并且在前期會產生明顯的停頓感,用戶體驗度不夠好;

  綜合上述分析,可以做出如下選擇:

  1、若僅僅是為了獲取某文件夾及其所有子文件夾的路徑的話,請選擇 dir /ad /b /s 語句;
  2、若需要過濾帶隱藏屬性的文件夾的話,for /r 和 dir 語句都可以實現,但 for /r 內存占用小,處理速度快,是上上之選;
  3、若需要獲取所有文件夾,則除了 dir /ad /b /s 外,別無選擇,因為 for /r 語句會遺漏帶隱藏屬性的文件夾;

  在實際的使用中,我更喜歡使用 for /f 和 dir 的組合,因為它不會產生遺漏,并能給我帶來更靈活的處理方式,唯一需要忍受的,就是它在處理大量路徑時前期的停頓感,以及在這背后稍微有點偏高的內存占用;在我追求速度且可以忽略帶隱藏屬性的目錄的時候,我會換用 for /r 的方案,不過這樣的情形不多——有誰會愿意為了追求速度而容忍遺漏呢?
1

評分人數

    • red88: 知識寫得簡單明了,十分感謝呀!技術 + 1
尺有所短寸有所長,學好批處理沒商量;
考慮問題復雜化,解決問題簡潔化。

心在天山,身老滄州。

TOP

本帖最后由 Hello123World 于 2011-9-18 13:24 編輯

五、僅僅為了匹配第一層目錄而存在:for /d

  for /d 中 /d ,完整的含義是 /directory,本意是為了處理文件夾,它的完整語句應該是這樣的:
for /d %%i in (元素集合) do 命令語句集合

  當“元素集合”中包含有通配符?或*時,它會匹配文件夾,但是,相比 for /r 而言,這個時候的for /d,其作用就小得可憐了:它僅能匹配當前目錄下的第一級文件夾,或是指定位置上的文件夾,而不能匹配更深層次的子文件夾。

  例如:for /d %%i in (d:\test*) do echo %%i 這樣的語句 ,會匹配到形如:d:\test、d:\test1、d:\test2之類的文件夾,若不存在這樣的路徑,將不會有任何回顯。

  當“元素集合”中不包含任何的通配符時,它的作用和 "for %%i in (元素集合) do 命令語句集合" 這樣的語句別無二致。

  因此,for /d 的角色就變得很微妙了:當“元素集合”中包含通配符?或*時,它的作用就是匹配文件夾,此時,它僅能匹配當前目錄下的第一級文件夾,或是指定位置上的文件夾,在層次深度上不及 for /r,但和 for /r 一樣的壞脾氣:不能匹配帶隱藏屬性的文件夾;在靈活性上不及for /f和dir的組合;當“元素集合”中不包含任何統配符的時候,它完全是 "for %%i in (元素集合) do ……" 語句的翻版,但是又稍顯復雜。

  for /d 的作用是如此有限,我使用的次數是如此之少,以至于我一度找不到它的用武之地,認為它食之無味,棄之可惜,完全是雞肋一塊。

  某年某月,我在cmd窗口里寫下了這樣的代碼:
[code24]
  1. for /d %i in (test*) do @echo %i
復制代碼
  我的本意是想查看在我的臨時目錄下,長年累月的測試工作到底建立了多少測試文件夾,以便我隨后把echo換成rd刪除之。這個時候,我發現這條代碼是如此的簡潔,是 for /r 或 for和 dir /ad /b 的組合所無法替代的(echo換成rd就可以直接刪除掉這些測試目錄)。

  簡潔的代碼給我帶來的喜悅僅僅持續了短短10幾秒的時間,我便開始了迷惘——能用到for /d的類似情形,貌似少之又少且乏善可陳啊。

hello123world注:正如qzwqzw所言,for /r /d是可以一起使用的;【在for有限的4個參數中,據我所知只有/r /d可以一起使用】。
例如:
  1. @echo off
  2. For /r /d %%i in (*) do echo %%i
  3. pause>nul
復制代碼
效果:
顯示當前目錄下所有的文件夾【包括子文件夾】;等價于 "dir /ad /s /b"。

for /r /d 其實是對 /d 參數的擴展,/d參數本身只能處理第一層文件夾,但是加上/r參數后就可以處理所有的子文件夾;
for /r /d依然不能處理隱藏文件夾。
這里給出使用for /r /d的一般條件:
1.要對文件夾進行操作(dir /ad /s /b可以顯示,但不能對文件夾進行操作);
2.不處理隱藏文件夾(說到底,還是for /f 和dir結合的命令更強大些)。
2

評分人數

    • Hello123World: 畢竟是2年前的老帖,值得原諒技術 + 1
    • qzwqzw: 如果你知道for /d是可以和/r聯用,你還覺得 ...技術 + 1
尺有所短寸有所長,學好批處理沒商量;
考慮問題復雜化,解決問題簡潔化。

心在天山,身老滄州。

TOP

六、計數循環:for /l

  /l者,/loop的縮寫是也,從鳥語翻譯過來,loop就是循環的意思。實際上,所有的for語句,都可以看成是一種“循環”,只是在/l中,特指按照指定次數進行循環罷了。

  for /l 語句的完整格式是這樣的:for /l %%i in (x,y,z) do (……),在這個語句中,x、y和z都只能取整數,正負皆可,x指代起始值,y指代步長,z為終止值,具體含義為:從x開始計數,以y為步長,直至最接近z的那個整數值為止,這之間有多少個數,do后的語句就執行多少次。

  舉個具體的例子:
[code25]
  1. for /l %%i in (1,2,10) do echo bathome
復制代碼
  在以上的代碼中,初始值是1,步長為2,終止值為10,表明計數從1開始,每隔2個數計算一次,直至最接近10的那個整數,羅列出來,就是1,3,5,7,9,再下一個就是11,超過10了,不再計算在內,所以,do后的語句只執行5次,將連續顯示5個bathome。

  實際上,x,y和z的值可正可負,甚至為0,限制非常寬松:

  1、步長y的值不能為0;
  2、當步長y的值為正整數時,終止值z不能小于初始值x;
  3、當步長y的值為負整數的時候,終止值z不能大于初始值x。

  換而言之,必須保證in和do之間能取到一個有效的數組序列。

  例如:
[code26]
  1. for /l %%i in (-1,2,5) do echo bathome
復制代碼
[code27]
  1. for /l %%i in (5,-2,-1) do echo bathome
復制代碼
  以上兩條代碼的功能完全一樣,都將顯示4次bathome,區別就在于[code26]是正序計算,而[code27]是逆序計數而已。

  以下幾條代碼都是有問題的:
[code28]
  1. for /l %%i in (1,0,1) do echo bathome
復制代碼
[code29]
  1. for /l %%i in (2,1,1) do echo bathome
復制代碼
[code30]
  1. for /l %%i in (1,-1,2) do echo bathome
復制代碼
  其中,[code28]違反了步長不能為0的限制,將陷入無限循環中;[code29]和[code30]都犯了同樣的錯誤:無法獲得有效的數列元素,導致in和do之間取到的值為空元素,從而使得整條for語句無從執行。

  當大家明白了 for /l 的具體功能之后,是否會想到了與它有異曲同工之妙的goto循環語句呢?似乎,for /l 和 goto 循環語句可以相互替換?

  一般而言,for /l語句可以換成goto循環,但是,goto循環并不一定能被 for /l 語句替換掉。具體原因,請大家仔細想想,我在此不再詳細解說,只是就大家非常關心的一個問題提供一個簡潔的答案,那就是:什么時候該用 for /l 計數循環,而什么時候又該用goto條件循環?

  答案非常簡單:當循環次數確定的時候,首選 for /l 語句,也可使用goto語句但不推薦;當循環次數不確定的時候,用goto語句將是唯一的選擇,因為,這個時候需要用if之類的條件語句來判斷何時結束goto跳轉。

[ 本帖最后由 namejm 于 2010-12-25 02:02 編輯 ]
尺有所短寸有所長,學好批處理沒商量;
考慮問題復雜化,解決問題簡潔化。

心在天山,身老滄州。

TOP

  后記:

  當Windows為我們打開了五彩繽紛的圖形窗口的時候
  DOS命中注定會隕落
  CMD毫無懸念將萎縮
  批處理逐漸趨向無聲無息
  而powershell的到來,無疑會讓更多的人忘記批處理
  這是一門即將失傳的技藝
  這是一塊行將就木的領域
  然而,命令行工具仍然具有批量處理一切的巨大威力
  字符界面仍然是高效操作的代名詞
  曾為批處理的方便靈活而擊節贊賞
  曾被批處理的簡潔快速深深折服
  一直以來,總想為批處理的推廣做些什么
  于是,從在CN-DOS里盡職盡責地為大家解答疑問,到創辦了自己的論壇專職答疑解惑,再到無怨無悔地碼字寫教程,一步步走來,喜怒哀愁,五味雜陳
  直至如今辭去站長等一切管理職務,逐漸淡出批處理圈子
  夢依舊在,只是,心有余而力漸有不足
  這篇從入門到精通的教學帖,從2008年10月開貼到現在,不知不覺拖拖拉拉竟然過去了兩年有余
  每每看到跟帖的會員在問什么時候有更新
  心中總有一絲愧疚
  今天,終于抽空對它做個了斷
  只是,年年歲歲花相似,歲歲年年人不同
  繁雜的事務使我已不再有當初的心境
  for /l 部分總有虎頭蛇尾的感覺
  只能向各位說聲抱歉了
  在我徹底淡出批處理圈子之前
  我只能盡我所能地向各位傾我所學了
  最后,我希望論壇的管理人員能按照頂樓的管理提示經常為這個帖子抽抽水
  或者是為了大家閱覽的方便而永久鎖定這個帖子

[ 本帖最后由 namejm 于 2010-12-25 02:00 編輯 ]
1

評分人數

    • salad: namejm深入淺出地闡述了bat技術 + 1
尺有所短寸有所長,學好批處理沒商量;
考慮問題復雜化,解決問題簡潔化。

心在天山,身老滄州。

TOP

占位編輯
尺有所短寸有所長,學好批處理沒商量;
考慮問題復雜化,解決問題簡潔化。

心在天山,身老滄州。

TOP

期待能學到更多知識
【批處理在線視頻分享】http://bbs.bathome.net/thread-31727-1-1.html
【微信公眾號、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html

我幫忙寫的代碼不需要付錢,不用找我要支付寶或微信賬號。如果一定要給,請到微信群給大家發紅吧。

TOP

怎么沒了,真看得好呢

TOP

通俗易懂!非常謝謝樓主
不管黑貓白貓,會捉老鼠的貓就是好貓!

TOP

對新手來說真的是太好了。謝謝
有些緣分是注定要失去的

TOP

for %%a in ("1.txt" "2.txt" "3.txt") do echo >%%a

TOP

返回列表
36选7开奖结果今天福建 东方6十1机选 一分彩彩计划群 12093期排列3开奖结果 南京期货配资晓晓 彩吧论坛福彩3d预测总汇 北京pk拾官网开奖 河南11选5开奖号码 中卫期货配资 街机急速赛车 广东11选5定位走势图 江苏11选5一定牛 江苏十一选五走势图表 app 好彩1复式6个号码 福彩山东11选5技巧 青海快3开奖结果今天75 下载重庆快乐十分走势图